;;;QQ:67762207
[@SurviveGameMainMenu]
{
#IF
IsAdmin
#SAY
{FCOLOR/10}管理员菜单{FCOLOR/12} \\
<开始幽灵地狱挑战游戏。/@BeginSurviveGameMainMenu> \
<初始化幽灵地狱挑战游戏。/@InitalSurviveGameMainMenu> \\
{FCOLOR/10}使用者菜单{FCOLOR/12} \\

#IF
#SAY
我来说明一下幽灵地狱挑战游戏规则。\
在限定的时间里，如果[生存者多于25人]或者[剩下的怪物多于15个]就算失败。\
<参加幽灵地狱挑战游戏。/@JoinSurviveGameMainMenu> \


[@BeginSurviveGameMainMenu]
#CALL [EventSystem\SurviveGame\SurviveGame.txt] @TestSurviveGame_Start

[@InitalSurviveGameMainMenu]
#CALL [EventSystem\SurviveGame\SurviveGame.txt] @TestSurviveGame_Finish



[@JoinSurviveGameMainMenu]
#CALL [EventSystem\SurviveGame\SurviveGame.txt] @TestSurviveGame_Join
}

[@TestSurviveGame_Start]
{
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启
;; 防止活动启动2次
#IF
equal D1 0
#ACT
LineMsg "Grobal" "(活动公告):幽灵地狱挑战游戏将在1分钟后开始,要参加的玩家到道馆402:119进入游戏！"
Delaygoto "Grobal" 60 @TestSurviveGame_Start_Next1 10030
break

[@TestSurviveGame_Start_Next1]
#IF
#ACT
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 1
ResetMapAttr "RUSH1"
MonClear RUSH1
LineMsg "Grobal" "(!) 幽灵地狱挑战游戏开始了，想参加的人请在5分钟内入场,要参加的玩家到道馆402:119进入游戏！"
mov N5 2            ;;AC,定义怪物的攻击和防御==
mov N6 4            ;;MAC
mov N7 40	    ;;HP	
mov N8 4            ;;DC

#IF
#ACT
mov B0 "触角神魔"
mov N0 14
mov B1 "恶形鬼"
mov N1 18
mov B2 "犬猴魔"
mov N2 14
mov B3 "爆毒神魔"
mov N3 18
mov B4 "霸王守卫"
mov N4 2

#IF
#ACT
mov A5 ""
Addstr A5 B1
Addstr A5 ","
Addstr A5 B2
Addstr A5 ","
Addstr A5 B3
Addstr A5 ","
Addstr A5 B4
;;A5=触角神魔,恶形鬼,犬猴魔,爆毒神魔,霸王守卫
Delaygoto "Grobal" 300 @TestSurviveGame_Start_Next3 10030

[@TestSurviveGame_Start_Next3]
#ACT
mov N11 1
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 2
LineMsg "Grobal" "(活动公告):幽灵地狱挑战游戏进入通道已经关闭！"
goto @TestSurviveGame_Start_Next4

[@TestSurviveGame_Start_Next4]
#IF
Elarge N11 11
#ACT
goto @TestSurviveGame_Start_Result
break
#ELSEACT
EventMsg "RUSH1" " 第'<$OUTPUT(N11)>'队怪物出场，怪物将渐渐变强请小心。"
MonGenP "RUSH1,40,40,30" %B0 %N0
MonGenP "RUSH1,40,40,30" %B1 %N1
MonGenP "RUSH1,40,40,30" %B2 %N2
MonGenP "RUSH1,40,40,30" %B3 %N3
MonGenP "RUSH1,40,40,30" %B4 %N4
MonPwr "RUSH1" %A5 [AC] %N5
MonPwr "RUSH1" %A5 [MAC] %N6
MonPwr "RUSH1" %A5 [HP] %N7
MonPwr "RUSH1" %A5 [DC] %N8
Inc N11 1
Inc N5 1            ;;AC,定义怪物的攻击和防御==
Inc N6 2            ;;MAC
Inc N7 10	    ;;HP	
Inc N8 2            ;;DC
ChangeMonLevel "RUSH1" %A5 99
Delaygoto "Grobal" 180 @TestSurviveGame_Start_Next4 10031

[@TestSurviveGame_Start_Result]      ;;挑战屋结果
#IF
CheckMonMap RUSH1 15
or CheckHum RUSH1 25

#ACT
MapTing RUSH1 1 403 122
MonClear RUSH1
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 0
LineMsg "Grobal" "(活动公告) :幽灵地狱挑战游戏失败。"
Delaygoto "Grobal" 3600 @TestSurviveGame_Start_Result_Ready 10033

#ELSEACT
ChangeMapAttr "RUSH1" "SAFE"
MonClear RUSH1
MapTing RUSH1 RUSH1 40 40
LineMsg "Grobal" "(活动公告) : 幽灵地狱挑战游戏挑战成功。"
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 0
GiveExpMap RUSH1 10000000
DropItemMap "RUSH1,40,40,20" 积分卷 1 10
Delaygoto "Grobal" 3600 @TestSurviveGame_Start_Result_PreReady 10033

[@TestSurviveGame_Start_Result_PreReady]
#ACT
MapTing RUSH1 1 403 122
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 0
MonClear "RUSH1"
MapTing RUSH1 1 403 122
ClearDelaygoto 10030
ClearDelaygoto 10031
ClearDelaygoto 10032
ClearDelaygoto 10033
}

[@TestSurviveGame_Finish]
{
#SAY
真想结束挑战屋游戏活动吗? \\
<是/@TestSurviveGame_Finish_ConFirm> \
<不是/@exit> \\

[@TestSurviveGame_Finish_ConFirm]
#ACT
LineMsg "Grobal" "(活动公告):幽灵地狱挑战游戏结束了。"
SAVEVALUE  "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启 0
MonClear "RUSH1"
MapTing RUSH1 1 403 122
ClearDelaygoto 10030
ClearDelaygoto 10031
ClearDelaygoto 10032
ClearDelaygoto 10033
Close
}

[@TestSurviveGame_Join]
{
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [幽灵地狱挑战游戏] 游戏开启

#if
equal D1 1
#ELSESAY
现在不能参加幽灵地狱挑战游戏。\\
<关  闭/@exit>
#elseact
break

#IF
CheckGold 50000
#ACT
Take 金币 50000
Map RUSH1
break
#ELSESAY
您的钱不够... \\
<关  闭/@exit>
}
;;;QQ:67762207