;;;QQ:67762207
[@IslandMainMenu]
{
#IF
IsAdmin
#SAY
{FCOLOR/10}管理员菜单{FCOLOR/12} \
<初始化生存游戏场地活动。/@InitalIslandEvent> \
<开始黄金岛生存游戏。/@BeginIslandEvent> \\
{FCOLOR/10}使用者菜单{FCOLOR/12} \

#IF
#say
我来说明一下生存游戏场地生存游戏的规则。\\
游戏方法是活动开始后20分钟内可以重新入场，生存者人数3名以内时游戏才会结束。\
游戏结束时生存者全部会被召唤到生存游戏场地的中央分取宝物。\
生存游戏场地生存游戏的限定时间是1小时, 在限定时间以后人数是5名以上的话，生存游戏将失败。\
并且在生存游戏场地看不到自己和他人的名字。\
{FCOLOR/10}请注意在黄金岛生存游戏场地所有的攻击力都会变强。{FCOLOR/12} \\
<参加黄金岛生存游戏。/@JoinIslandEvent> \

[@InitalIslandEvent]
#CALL [EventSystem\IslandGame\IslandGame.txt] @FinishIsland

[@BeginIslandEvent]
#CALL [EventSystem\IslandGame\IslandGame.txt] @StartIsland

[@JoinIslandEvent]
#CALL [EventSystem\IslandGame\IslandGame.txt] @JoinIsland
}

[@StartIsland]
{
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启

#if
equal D1 0
#ACT
LineMsg "Grobal" "(*) 黄金岛生存游戏1分钟后开始,要参加的玩家到道馆402:119进入游戏！"
Delaygoto "Grobal" 60 @OpenGateGoldenIsland 10010
break

[@OpenGateGoldenIsland]
#ACT
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 1
LineMsg "Grobal" "(*): 黄金岛生存游戏开始了。要参加的玩家到道馆402:119进入游戏！"
ResetMapAttr "E003"
SetEventDamage E003 7 ;;设置地图怪物攻击倍率?
SetEventMap "E003"
ChangeMapAttr "E003" "NOCHAT"
mov N1 0          ;;N1刷怪时间计算，间隔20秒
mov N2 0          ;;N2时间计算，间隔1分钟 
goto @GenMonkeys
goto @CheckFinishCondition

[@GenMonkeys]         ;;此函数为一个不断循环的函数，用来刷怪和集结怪物
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启

#IF
Equal D1 0     ;;如果生存游戏还没有开始或者已经结束了
#ACT
break

#IF
!CheckMonMap "E003,40,40,40" 90 看场怪
#ACT
MonGenP "E003,40,40,30" 猿猴战将 45 "noitem"
MonGenP "E003,40,40,30" 猿猴战士 45 "noitem"
MonGenP "E003,40,40,30" 魔神怪1 20 "noitem"
ChangeMonLevel "E003" "猿猴战将" 99
ChangeMonLevel "E003" "猿猴战士" 99
ChangeMonLevel "E003" "魔神怪1" 99
ApplyMonEx "E003,40,40,40" 猿猴战将 [MonsterSide] "看场怪"
ApplyMonEx "E003,40,40,40" 猿猴战士 [MonsterSide] "看场怪"
ApplyMonEx "E003,40,40,40" 魔神怪1 [MonsterSide] "看场怪"

#IF
Equal N2 2  ;;40秒让怪物重新集结一次
#ACT
ApplyMonMission "E003, 40, 40, 40,9999" "看场怪" "E003,40,40"

#IF
Equal N2 4 ;;80秒让怪物重新分布到4个地方
#ACT
ApplyMonMission "E003, 40, 40, 30, 10" "看场怪" "E003, 16, 18"
ApplyMonMission "E003, 40, 40, 30, 10" "看场怪" "E003, 16, 55"
ApplyMonMission "E003, 40, 40, 30, 10" "看场怪" "E003, 66, 16"
ApplyMonMission "E003, 40, 40, 30, 10" "看场怪" "E003, 66, 55"

#IF
Equal N2 8 ;;160秒的时候清空怪物
#ACT
mov N2 0
MonClear "E003" "看场怪"
goto @GenMonkeys
break

#IF
#ACT
Inc N2 1             ;;+1
DelayGoto "Grobal" 20 @GenMonkeys 10011 ;;循环调用

[@CheckFinishCondition]          ;;检查完成条件
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启

#IF
Equal D1 0
#ACT
break

#IF
Equal N1 20 ;;20分钟后不允许在进入生存游戏
#ACT
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 2
LineMsg "Grobal" "(*) :黄金岛生存游戏进入通道已经关闭"

#IF
ELarge N1 20 ;;20分钟如果地图上没有人，任务失败
!CheckHum "E003" 1
#ACT
goto @IslandEvent_Fail
break

#IF
ELarge N1 20 ;;20分钟后地图内少于4人
!CheckHum "E003" 4
#ACT
goto @IslandReward
break

#IF
Equal N1 23 ;;23分钟集结一次玩家
#ACT
MapTing E003 E003 40 40

#IF
Equal N1 25 
#ACT
MapTing E003 E003 40 40

#IF
Equal N1 28
#ACT
MapTing E003 E003 40 40

#IF
Equal N1 29
#ACT
MapTing E003 E003 40 40

#IF
ELarge N1 30 
#ACT
goto @IslandEvent_Fail
break

#IF
CheckHum "E003" 0
#ACT
LineMsg "E003" "(!) 生存游戏场地里有<$OUTPUT(P9)>名生存。"
LineMsg "E003" "(!) 生存游戏场地生存游戏已经过了'<$OUTPUT(N1)>'分钟。"
Inc N1 1
DelayGoto "Grobal" 60 @CheckFinishCondition 10012  ;;60秒钟循环一次
break

[@IslandEvent_Fail] ;;生存游戏失败
#ACT
MapTing E003 1 403 122
MonClear "E003"
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 0
LineMsg "Grobal" "(活动公告) :黄金岛生存游戏失败了。"
Delaygoto "Grobal" 3600 @GoldIslandReadyCorrect 10014 ;;2个小时后初始化生存游戏
break

[@IslandReward]
#ACT
ChangeMapAttr "E003" "SAFE"
MonClear "E003"
LineMsg "Grobal" "(活动公告) :黄金岛生存游戏成功了。"
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 0
MapTing E003 E003 40 40
Delaygoto "Grobal" 300 @TingCorrect 10013
GiveExpMap E003 10000000
DropItemMap "E003,40,40,15" 积分卷 1 10 ;;地图掉落物品

[@TingCorrect]
#ACT
MapTing E003 1 403 122
Delaygoto "Grobal" 3600 @GoldIslandReadyCorrect 10014


[@GoldIslandReadyCorrect]
#ACT
;;LineMsg [Grobal] "(!) 可以启动黄金岛生存游戏了。"
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 0
ClearDelaygoto 10010
ClearDelaygoto 10011
ClearDelaygoto 10012
ClearDelaygoto 10013
ClearDelaygoto 10014
}

[@FinishIsland]
{
#SAY
真想结束生存游戏场地活动吗? \\
<是/@FinishIsland_Confirm> \
<不是/@exit> \\

[@FinishIsland_Confirm]
#ACT
LineMsg "Grobal" "(!) 黄金岛生存游戏结束了。"
SAVEVALUE  "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启 0
MonClear "E003"
MapTing E003 1 403 122
ClearDelaygoto 10010
ClearDelaygoto 10011
ClearDelaygoto 10012
ClearDelaygoto 10013
ClearDelaygoto 10014
Close
}

[@JoinIsland]
{
#if
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启

#IF
Equal D1 1
#act
goto @JoinGoldenIsland
#ELSESAY
现在不能参加黄金岛生存游戏。\\
<关  闭/@exit>

[@JoinGoldenIsland]
#act
MOV D1 0
loadvalue D1 "ParamControl\活动设置.ini" [黄金岛生存游戏] 游戏开启

#IF
Equal D1 1
CheckGold 50000                 ;;如果不是则收取FLD_FARE里面注明的金币数量!
#ACT
Take 金币 50000
Map E003
break
#ELSESAY
钱不够... \\
<关  闭/@exit>
}
;;;QQ:67762207