;;feifan=============================================================
[@混乱PK赛]
{
#ACT
MOV D1  0
MOV D4  0
MOV D2  0
MOV  A1 ""
loadvalue A1 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] PK王名字
loadvalue D4 "PlayerParam\混乱PK大赛.ini" [获胜次数] %A1
#IF
checkhum kt0001
#SAY
上一界PK王是：{FCOLOR/10}<$OUTPUT(A1)>{FCOLOR/12}，总共获胜{FCOLOR/10} <$OUTPUT(D4)> {FCOLOR/12}场\\
你要参加混乱PK大赛吗？获胜者奖励如下:\
1.获胜者将赢得{FCOLOR/1}50点声望{FCOLOR/12}.\
2.在排行榜上显示你自己的名字，获得{FCOLOR/1}PK王{FCOLOR/12}称号.\
3.获胜者拥有上线{FCOLOR/1}全服红字提示{FCOLOR/12}的功能,\
__显示荣耀，提高你的知名度 ^_^\
================规则如下==================\
限制最高{FCOLOR/2}30人{FCOLOR/12}参加,开始{FCOLOR/2}5分钟{FCOLOR/12}为进入和准备时间.\
如果5分钟内参加人数不足5人,则取消本次比赛.\
混乱PK无级别和职业限制,战士不能吸人,道士不能用复活\
在PK场地里,是看不到自己和他人名字的.\
在PK场地里,是不爆任何装备的.\
复活无效,躺下就被传出去,场内不能买药,也不准带药!\
每11分钟场地出现火墙，千万小心\
每10分钟会砸下100个{FCOLOR/2}万年雪霜{FCOLOR/12}。少于5人则不会掉落。\
在PK场地里，杀至只剩下你自己一个人，那你就获胜!\
掉线将失去比赛资格.{FCOLOR/2}胜利后请等待裁判在地图上方出现{FCOLOR/12}\\
<同意规则，进入赛场，为荣誉而战！/@进入PK赛>     当前<$OUTPUT(P9)>人  <刷新/@混乱PK赛>\\
<关闭/@exit>\




[@进入PK赛]
#ACT
loadvalue D2 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启

#IF
CheckHum "kt0001" 30 
#SAY
对不起，比赛人数已满。最高30人参加。请等待下一场比赛.\
<关闭/@exit>\
#ACT
break

#IF
Equal D2 2
#SAY
目前比赛进行中，不能再参加，等下一场吧。\
<关闭/@exit>\
#ACT
break

#IF
Equal D2 0
#SAY
目前比赛未启动。\
<关闭/@exit>\
#ACT
break

#IF
checkitem 金创药（小） 1
OR checkitem 魔法药（小） 1
OR checkitem 金创药（中） 1
OR checkitem 魔法药（中） 1
OR checkitem 金创药（大） 1
OR checkitem 魔法药（大） 1
OR checkitem 金创药（特） 1
OR checkitem 魔法药（特） 1
OR checkitem 强效太阳水 1
OR checkitem 太阳水 1
OR checkitem 人参 1
OR checkitem 万年雪霜 1
OR checkitem 鸡血 1
OR checkitem 烧酒 1
#SAY
{FCOLOR/10}参加比赛是不能带药的！加血加魔法的物品都不能带入\
比赛中每隔10分钟会掉落100个万年血霜\
进入的时候会送你20个万年血霜\
现在请把包袱里药品全部清除掉再参加比赛{FCOLOR/12}\
<关闭/@exit>\
#ACT
break

#IF
checkmonRecall
#ELSESAY
你不能带宠物进去，但是你可以在里面召唤出宠物.\
#ELSEACT
break

#IF
Equal D2 1
#ACT
give 万年雪霜 20
SYSMSG "现在是比赛预备期间,禁止使用魔法,比赛开始后可以使用.如果赢得比赛,裁判将出现最上方"
SYSMSG "系统赠送20个万年雪霜，比赛中每隔10分钟掉落100个万年血霜,不要浪费药物."
MAPMOVE kt0001  26 15
break

}
;;40 14
;;feifan=============================================================

[@混乱PK裁判]
{
#ACT
loadvalue A1 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] PK王名字
loadvalue D4 "PlayerParam\混乱PK大赛.ini" [获胜次数] %A1

loadvalue D1 "PlayerParam\混乱PK大赛.ini" [获胜次数] %USERNAME
loadvalue D2 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启
INC D1 1

#IF
Equal D2 0
#ACT
SYSMSG "比赛没有开启."
break


#IF
Equal D2 1
#ACT
SYSMSG "比赛还没开始,现在是比赛准备期间."
break

#IF
!CheckHum "kt0001" 2
#ACT
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 产生PK王 1
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] PK王名字 %USERNAME
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启 0
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [获胜次数] %USERNAME %D1
actcmd SETFAME  + 50
SYSMSG "您赢得本次混乱PK赛冠军，获得50声望，您的名字被刻在排行榜上了，并且可设置是否上线全服提示"
MapTing kt0001 1 403 122
break

#ELSESAY
上一界PK王是：{FCOLOR/10}<$OUTPUT(A1)>{FCOLOR/12}，总共获胜{FCOLOR/10} <$OUTPUT(D4)> {FCOLOR/12}场\\
PK赛还没结束呢，你想中途退出还是想继续打？\\

<我要退出比赛/@tueichubisai>\\
<继续比赛/@exit>\\


[@tueichubisai]
#SAY
真的要退出吗？？你这个胆小鬼。。。\\
我现在就踢你出去！\\
<是的,我要退出比赛/@chuqufei>\\
<继续比赛/@exit>\

[@chuqufei]
#ACT
MAPMOVE 0 425 372
break

[@getback]
#ACT
close

}
;;feifan=============================================================

[@PK赛EI执行]
{
#IF
#ACT
SendCmd  "kt0001,25,10" 混乱PK裁判 Hide  ;;NPC隐藏
ResetMapAttr "kt0001"   ;;恢复默认
ChangeMapAttr "kt0001" "SAFE" 
ChangeMapAttr "kt0001" "NoSpell"
LineMsg "Grobal" "(*) 混乱PK大赛5分钟后开始,要参加的玩家到道馆402:119“活动管理员”进入赛场！"
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启 1
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 产生PK王 0
Delaygoto "Grobal" 60 @jingxingPK5 10021
break

[@jingxingPK5]
#IF
#ACT
LineMsg "Grobal" "(*) 混乱PK大赛4分钟后开始,要参加的玩家到道馆402:119“活动管理员”进入赛场！"
Delaygoto "Grobal" 60 @jingxingPK4 10022
break


[@jingxingPK4]
#IF
#ACT
LineMsg "Grobal" "(*) 混乱PK大赛3分钟后开始,要参加的玩家到道馆402:119“活动管理员”进入赛场！"
Delaygoto "Grobal" 60 @jingxingPK3 10022
break



[@jingxingPK3]
#IF
#ACT
LineMsg "Grobal" "(*) 混乱PK大赛2分钟后开始,要参加的玩家到道馆402:119“活动管理员”进入赛场！"
Delaygoto "Grobal" 60 @jingxingPK2 10023
break

[@jingxingPK2]
#IF
#ACT
LineMsg "Grobal" "(*) 混乱PK大赛1分钟后开始,要参加的玩家到道馆402:119“活动管理员”进入赛场！"
Delaygoto "Grobal" 60 @jingxingPK1 10023
break

[@jingxingPK1]
#IF
CheckHum "kt0001" 5 ;;是否达到比赛要求人数
#ACT
mov  D5 0
mov  D6 0
ResetMapAttr "kt0001"   ;;恢复默认
SetEventMap "kt0001"    ;;设置地图
ChangeMapAttr "kt0001" "NOCHAT"  ;;禁止说话
LineMsg "Grobal" "(*) 混乱PK大赛现在开始了,让我们期待最强PK王的诞生！"
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启 2
goto @检测PK人数
#ELSEACT
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启 0
LineMsg "Grobal" "(*) 由于未达到足够的人数，这次混乱PK大赛取消！"
ResetMapAttr "kt0001"   ;;恢复默认
MapTing kt0001 1 403 122
ClearDelaygoto 10021
ClearDelaygoto 10022
ClearDelaygoto 10023
Close

[@检测PK人数]
#ACT
loadvalue D3 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 产生PK王
inc D5  1
inc D6  1

#IF
!CheckHum "kt0001" 2
#ACT
SendCmd  "kt0001,25,10" 混乱PK裁判 Show  ;;显示NPC

#IF
!CheckHum "kt0001" 2
Equal D3 1
#ACT
loadvalue A1 "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] PK王名字
loadvalue D4 "PlayerParam\混乱PK大赛.ini" [获胜次数] %A1
LineMsg "Grobal" "(*) 今天的PK王已经诞生了！他就是“<$OUTPUT(A1)>”胜<$OUTPUT(D4)>场,让我们用鲜花或鸡蛋来祝贺他吧！！"
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 产生PK王 0
SAVEVALUE  "PlayerParam\混乱PK大赛.ini" [混乱PK大赛] 活动开启 0
ResetMapAttr "kt0001"   ;;恢复默认
MapTing kt0001 1 403 122
ClearDelaygoto 10024
break

#ELSEACT
Delaygoto "Grobal" 60 @检测PK人数 10024      ;;重复判断
GOTO @MAP动作
break

[@MAP动作]
#IF
CheckHum "kt0001" 2
Equal D6 11 ;;每11分钟放火墙
#ACT
MapSpell [Firewall] "kt0001,24,11,27,43, +d100, +t30, +h
MapSpell [Firewall] "kt0001,13,22,40,27, +d100, +t30, +h
MapSpell [Firewall] "kt0001,29,29,38,38, +d100, +t30, +h
MapSpell [Firewall] "kt0001,28,13,36,21, +d100, +t30, +h
mov  D6 0
break

#IF
CheckHum "kt0001" 5
Equal D5 10  ;10分钟掉落物品
#ACT
DropItemMap "kt0001,27,23,15" 万年雪霜 2 50    ;;地图掉落物品
mov  D5 0
break

}

;;feifan=============================================================