;NPC Release 1 (2003) By Geoff
;99% Translated NPCs Including Quests

;Wedding NPC - Lara - Serpent Valley
[@main]
#IF
check [800] 1
#ACT
goto @checki
#ELSEACT
goto @checki2

[@checki2]
#IF
check [800] 2
#ACT
goto @again
#ELSEACT
goto @main1

[@main1]
Hello <$USERNAME>. Are you in love? Come\
on don't be shy. Why don't you ask that\
special person for marriage. To get married\
you need happysugar as you may know. I\
know of a way to make it. Would you like me\
to make you some?\ \
<Yes/@yes> please

[@yes]
Ok but I need some ingredients first and of\
course a payment.\ \
<What Ingredients?/@ing>\
<How much payment?/@pay>\
<Carry on/@carry>

[@ing]
I will need:\
CannibalLeaf    5\
SpiderTooth     6\
CannibalFruit   3\
MaggotPill      4\
Bring me them and I will make it for you\ \
<Back/@yes>

[@pay]
The payment is 50000. You may think it is\
high but love costs <$USERNAME>.\ \
<Back/@yes>

[@carry]
Do you accept my offer?\ \
<Yes/@accept> I do\
<No/@noaccept> I don't

[@accept]
#IF
#ACT
SET [800] 1
goto @accept1

[@accept1]
Ok, go and get me those ingredients <$USERNAME>!\ \
<Ok/@exit>

[@checki]
#IF
checkitem CannibalLeaf 5
checkitem SpiderTooth 6
checkitem CannibalFruit 3
checkitem MaggotPill 4
#ACT
goto @goti
#ELSEACT
goto @noi

[@goti]
Well done you've got all the ingedients. But do you\
have the 50000 required?\ \
<Yes/@checkg>\
<No/@exit>

[@checkg]
#IF
checkgold 50000
#ACT
goto @gotall
#ELSEACT
goto @nocash

[@noi]
You don't have the ingredients required, get them\
and come back.\ \
<Ok/@exit>\
<What/@ingw> where the ingredients?

[@nocash]
You don't have the gold required, get it and come back.\ \
<Ok/@exit>

[@ingw]
I will need:\
CannibalLeaf    5\
SpiderTooth     6\
CannibalFruit   3\
MaggotPill      4\
Bring me them and I will make it for you\ \
<Ok/@exit>

[@gotall]
#IF
checkitem CannibalLeaf 5
checkitem SpiderTooth 6
checkitem CannibalFruit 3
checkitem MaggotPill 4
checkgold 50000
#ACT
goto @all
#ELSEACT
goto @notall

[@notall]
You don't have what I require, get it\
and come back.\ \
<Ok/@exit>

[@all]
#IF
#ACT
take CannibalLeaf 5
take SpiderTooth 6
take CannibalFruit 3
take MaggotPill 4
take gold 50000
give happysugar 1
SET [800] 2
#SAY
There you go <$USERNAME>, enjoy your wedding.\ \
<Thanks/@exit>

[@again]
You come back? Have you got divorced and want sugar\
to re-marry?\ \
<Yes/@yes>\
<No/@exit>