;무기
%100
+10
+11
;투구
+15

;대화, '*' : 대화 태그
[@main]
#IF
checkpkpoint 2
#SAY
자네와 같이 불량한 사람과는 거래 하고 싶지가 않군요.. \ \
<닫  기/@exit>
#ELSEACT
goto @main-1

[@main-1]
어서오세요.  무슨 일로 오셨나요?\ \
 옷을 <산다/@buy>\
 옷을 <판다/@sell>\
 옷을 <고친다/@repair>\
 <대화를 한다/@talkwith>\
 밖으로 <이동/@Tmove> \
 <그만둔다/@exit>
<>

[@Tmove]
#IF
random 4
#ACT
mapmove 0 318 303
break

#IF
random 4
#ACT
mapmove 0 318 302
break

#IF
random 4
#ACT
mapmove 0 307 312
break

#IF
random 4
#ACT
mapmove 0 308 311
break

#ELSEACT
goto @Tmove

[@buy]
무엇을 사시게요?\ \ \
 <뒤로/@main>

[@sell]
파실 옷을 올려보세요. 감정해 드릴께요.\
...투구나 모자도 취급하니까 왠만하면\
여기서 파세요.\ \
 <뒤로/@main>

[@repair]
옷,투구,모자를 수리할 수 있답니다.\ \ \
 <뒤로/@main>

[~@repair]
그런대로 잘 고쳐졌네요.\ \ \
 <뒤로/@main>

;#####################################################
;[109] 유의원의 위치를 알려줌
;[110] 이쁜이와 약속을 하지 않음
;[111] 금목걸이를 주웠다가 뺏음
;[112] 이쁜이와 친해짐 (남자인경우)
;[113] 이쁜이와 매우 친해짐
;[114] 이쁜이의 슬픈 스토리 시작

[@talkwith]
#IF
checkunit  [1] 0
#ACT
goto  @talkwith_1

;#####################################################

[@talkwith_1]

#IF
check [114] 1
#ACT
goto  @eppuni_sad_story
break

#IF
check [112] 1
#ACT
goto  @lover_eppuni
break
 
#IF
check [108] 1
check [109] 0
#ACT
goto  @talk_eppuni
break

#IF
daytime  day
#SAY
오늘은 날이 참 화창하네요.\
이렇게 좋은날은 남자친구랑 놀러가야\
되는데...\
#ACT
break

#IF
#SAY
어두운데 길 조심하세요. 요즘에 말이죠\
밤길에 강도들이 설친다고 난리에요.\
하루 빨리 강도들을 소탕해야 되는데..\


;-----------------------------------------------------

[@talk_eppuni]
#SAY
무슨일이시죠? 전 지금 일해야 되니거든요\
간단하게 물어 보세요\ \
 <유노의원에 대해서 물어본다/@talk_yu_doctor>\

[@talk_yu_doctor]
#IF
checkitemw  금목걸이 1
#SAY
아, 유의원할아버지를 말하는 거로군요.\
그런데 어떻하죠. 아무한테도 어디 있는지\
말하지 않겠다고 약속을 해서요.\ \
 착용하고 있는 <목걸이를 준다./@give_goldnecklace>\
#ELSESAY
아, 유의원할아버지를 말하는 거로군요.\
그런데 어떻하죠. 아무한테도 어디 있는지\
말하지 않겠다고 약속을 해서요.\
미안하지만 어쩔 수가 없네요.\
이만 돌아 가 주세요.\

[@give_goldnecklace]
#IF
checkitemw  금목걸이 1
#SAY
어머, 이 귀한걸 제게.. 이거 고마워서\
어쩌죠..  고마와요.. 정말 갖고 싶었던\
거였어요...\ \
 <유노의원에 대해 다시 물어본다./@talk_yu_again>\
#ACT
takew  금목걸이 1

[@talk_yu_again]
#IF
random 5
#SAY
이를 어쩌나... 선물까지 받았는데\
외면할 수도 없는 노릇이고....\
대신 제가 알려 드릴테니, 절대로\
유할아버지한테는 내가 알려줬다는 말은\
하지 말아 주세요. 꼭요, 약속해줘요?\ \
 <약속을 한다/@ok_make_promise>\
 <거절한다/@no_make_promise>\
#ELSESAY
안돼여... 말할 수 없어요.\
설마 목걸이를 준게 이 목적 때문은 이니겠죠?\
 <목걸이를 다시 돌려 달라고 한다./@getback_necklace>\
 <그럴리가 있느냐고 말한다./@noproblem>\

[@getback_necklace]
#SAY
흥... 당신 정말 저질이군요..\
자 받아요... 다신 이 가게에 얼신도 하지\
말아요... 흥.....
#ACT
give 금목걸이 1
set  [109]  1
set  [111]  1

[@noproblem]
#IF
gender man
random 20
#SAY
<$USERNAME> 당신은 정말 남자로군요.\
.. 앞으로는 오빠라고 부를 께요. 그래도 되죠?\
그리고 오빠랑 있으면 왠지 기분이 좋아져요.\
다음에 이곳을 또 들리면 꼭 저를 보러 오세요\
꼭 그래주실꺼죠?\
#ACT
set  [112] 1
#ELSESAY
당신은 정말 좋은 사람이군요...\
이 근처에 지나면 우리 가게에 꼭 들리세요\

[@ok_make_promise]
#SAY
꼭 그래 주세야 되여...\
유할아버지는 지금 자연동굴 지하에 계세요.\
제가 가보지는 못했기 때문에 자세히는\
모르구요. 거기서 몇 달 계신다고 하고\
가셨으니, 아마 거기 계실거에요.\
그럼, 유할아버지 만나더라고 제 얘기는\
절대 하지 말아주실꺼죠...\
#ACT
set  [109] 1

[@no_make_promise]
이런, 그렇다면 안되겠어요..\
전 유할아버지와 굳게 약속을 했거든요.\
제가 약속을 안지켰다는 걸 아시면 실망이\
크실꺼에요.\
미안해요...\ \
 <허의원의 부탁을 이야기 한다./@talk_her_order>\

[@talk_her_order]
#SAY
그런 사연이 있었군요...\
허의원 선생님 얘기라면 진작 말씀을\
하시지 그랬어요. 그럼담 알려 드리죠\
자연동굴 지하에 가 계신다고 하셨으니까\
거기로 가보세요.  더 자세한 건 저도 잘\
모르거든요. 그럼 꼭 찾으세요.\
#ACT
set  [109]  1
set  [110]  1


;-----------------------------------------------------

[@lover_eppuni]
#IF
check [109] 0
#SAY
<$USERNAME>오빠, 이번에는 또 무슨일로 왔어요.\
오빠를 도울 수 있는 일이라면 얼마든지 돕고 싶어요.\ \
 <유노의원에 대해서 물어본다./@about_yu_2>\
#ACT
break

#IF
random 5
#SAY
<$USERNAME>오빠, 지금은 몹시 피곤해요.\
미안해서 어쩌죠. 얘기를 들을 수가 없어요.\ \
 <착용하고 있는 목걸이를 선물로 준다./@give_my_necklace>\
#ACT
break

#IF
random 5
check [113] 1
#SAY
<$USERNAME>오빠, 지금은 몹시 피곤해요.\
미안해서 어쩌죠. 얘기를 들을 수가 없어요.\ \
 <착용하고 있는 목걸이를 선물로 준다./@give_my_necklace>\
 <착용하고 있는 반지를 선물로 준다./@give_my_ring>\
#ACT
break

#IF
#SAY
<$USERNAME>오빠, 심심하던 차에 잘 왔어요.\
저한테 재미있는 얘기 좀 해줘요.\
해줄 꺼죠 ?\ \
 <오마가 트름하는 얘기를 해준다./@talk_about_oma>\
#ACT
break

[@about_yu_2]
오빠니까 알려 드리는 거에요. 유할아버지는 지금\
자연동굴 지하에 있어요. 누구한테도 말하지 않기로\
약속 했으니까, 오빠도 절대로 얘기하면 안되요\
알았죠?\

[@talk_about_oma]
하하하하하.....\
너무 재밌어요. 오빠는 정말 재치 있는 사람이라니까\

[@give_my_necklace]
#IF
checkitemw  [NECKLACE]
#ACT
takew  [NECKLACE]
goto  @thanks_neckl
#ELSESAY
오빠는 농담도 잘 해...\
말만이라도 고마와...\

[@thanks_neckl]
#IF
random 5
#ACT
set [113] 1
#SAY
오빠, 이런 선물을 주다니 너무 좋아요\
기운이 나는것 같아요.\
#ELSESAY
오빠, 이런 선물을 주다니 너무 좋아요\
기운이 나는것 같아요.\


[@give_my_ring]
#IF
checkitemw  [RING]
#ACT
takew [RING]
#ELSESAY
오빠는 농담도 잘 해...\
말만이라도 고마와...\

#IF
istakeitem 해골반지
#ACT
goto  @eppuni_stroy_1
#ELSEACT
goto  @thanks_ring

[@thanks_ring]
정말요.. 이런걸 나한테 주다니...\
오빠, 쪽~~~\

[@eppuni_stroy_1]
#SAY
흐흐흐흐흑흑.....\
..............................\
고마와요... 이런 좋은 반지를 줘서...\
...........\
미안해요. 갑자기 몸이 않 좋아서...\
#ACT
set [114] 1


;-----------------------------------------------------
;이쁜이의 사연...

[@eppuni_sad_story]
오빠, 오늘은 별루 말하고 싶지 않아.\
미안... 다음에 다시와줘...\




;-----------------------------------------------------

[상품]
;젠되는 상품    물량       hour
평복(남)        50         1
평복(여)        50         1
경갑옷          50         1
은실치마        50         1
미갑주(남)      5          3
미갑주(여)      5          3
화염마의(남)    5          3
화염마의(여)    5          3
도신의(남)      5          3
도신의(여)      5          3
