[@main]
#IF
CHECKNAMELIST   ../Market_def/Challenge/finish.txt
#ACT
GOTO @complete

#ELSEACT
GOTO @nocomplete

[@nocomplete]
#IF
CHECK [830] 1
#ACT
GOTO @next

#ELSEACT
GOTO @trw

[@trw]
#IF
CHECK [829] 1
#ACT
GOTO @start-1

#ELSESAY 
well done <$USERNAME>.\
You have managed to complete all the previous stages.\
as your reward for killing the 4 Lords i would like to give you\
a choice of gifts.\ 
Please select a gift from the list below\ \

<1 x ChestAugrment/@chest>\
<1 x ChestOfHunt/@chesofhunt>\
<3 x DungeonScrolls/@scroll>\

[@chest]
#ACT
GIVE ChestAugrment 1
SET [829] 1
ADDNAMELIST    ../Market_def/Challenge/stage3.txt
GOTO @start-1

[@chesofhunt]
#ACT
GIVE ChestOfHunt 1
SET [829] 1
ADDNAMELIST    ../Market_def/Challenge/stage3.txt
GOTO @start-1

[@scroll]
#ACT
GIVE dungenscroll 3
SET [829] 1
ADDNAMELIST    ../Market_def/Challenge/stage3.txt
GOTO @start-1

[@start-1]
#SAY
Ok <$USERNAME>.\
Welcome to Stage Four of the Elysian Challenge.\
This is the final stage.\
If you choose to undertake this final challenge you will be\
rewarded with a RingOfGod.\
This last task is to kill Elysians EvolutionBoss.\ \

<I wish to undertake the last task/@next>\
<I do not wish to continue/@no>

[@next]
#IF
CHECK [830] 1
CHECKMONMAP YUT01 1
#SAY
Sorry <$USERNAME>.\
You must kill all of the monsters i have sent before\
you can go to the next room.\
Keep killing them untill they are all dead.\ \

<Exit/@exit>

#ELSEACT
GOTO @spawn

[@spawn]
#IF
CHECK [830] 1
#ACT
GOTO @end

#ELSEACT
PARAM1 YUT01
PARAM2 99
PARAM3 94
MONGEN Evolution3 1
SET [830] 1
BREAK
CLOSE

[@end]
#SAY
Congratualtions <$USERNAME>.\
You have completed this Elysian Challenge.\
Click on the Finish button below to collect your\
final reward.\ \

<Finish/@finish>

[@finish]
#ACT
ADDNAMELIST    ../Market_def/Challenge/finish.txt
SET [831] 1
GIVE RingOfGod 1
MAPMOVE 0 331 270
SENDALLMSG "<$USERNAME> has completed the Elysian Challenge.Well done!." 3
SENDALLMSG "<$USERNAME> has gained a RingOfGod from this challenge.Well done!." 3
BREAK
CLOSE

[@no]
#ACT
MAPMOVE 0 331 270
BREAK
CLOSE

[@complete]
#SAY
Sorry <$USERNAME>.\
It would appear that you have already compeleted this\
challenge.\
You may only do this challenge once.\ \

<Exit/@exit>








