;;Ҫɾ

[@Main]
#ACT
Mov A7 %GUILDNAME
Loadvalue A1 "QuestDiary\Guild\Palace.txt" %GUILDNAME [News]
#SAY
Welcome to {FCOLOR/10}<$OUTPUT(A7)>'s{FCOLOR/12} palace..\\
Current Guild News:\
{FCOLOR/10}<$OUTPUT(A1)>{FCOLOR/12}\\
<Merchant Status/@Merchant>\
<Guild Funds/@Guild_Funds>\
<Guild News/@News>\\
<Leave/@Exit>

;------------------------------------------------

[@News]
#IF
IsGuildMaster
#ACT
Loadvalue A1 "QuestDiary\Guild\Palace.txt" %GUILDNAME [News]
#SAY
Current News:\\
{FCOLOR/10}<$OUTPUT(A1)>{FCOLOR/12}\\
<Change News/@@ChangeNews>\
<Leave/@Exit>
#ELSESAY
Only leader can change the news...\\\
<Leave/@Exit>

[@@ChangeNews]
#ACT
Mov A2 %INPUTSTR
SaveValue "QuestDiary\Guild\Palace.txt" %GUILDNAME [News] %A2
CLOSE

;------------------------------------------------

[@Merchant]
#ACT
Loadvalue A1 "QuestDiary\Guild\Palace.txt" %GUILDNAME [Potion]
Loadvalue A2 "QuestDiary\Guild\Palace.txt" %GUILDNAME [Repair]
Loadvalue A3 "QuestDiary\Guild\Palace.txt" %GUILDNAME [PotionPurchase]
Loadvalue A4 "QuestDiary\Guild\Palace.txt" %GUILDNAME [RepairPurchase]

#SAY
"" Means not hired...\\
Potion Shop: "{FCOLOR/10}<$OUTPUT(A1)>{FCOLOR/12}" Will work untill "{FCOLOR/10}<$OUTPUT(A3)>{FCOLOR/12}"\\
Repair Shop: "{FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}" Will work untill "{FCOLOR/10}<$OUTPUT(A4)>{FCOLOR/12}"\\
<Leave/@Exit>

;------------------------------------------------

[@Guild_Funds]
#IF
IsGuildMaster
#ACT
Loadvalue A2 "QuestDiary\Guild\GoldStorage.txt" %GUILDNAME [Gold]
#SAY
{FCOLOR/10}Legends Gold Storage{FCOLOR/12}\
Current Gold: {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\\
What do you wish to do?\\
<Input Amount Of Gold To Deposit Gold/@@DepositGold>\
<Input Amount Of Gold To With Draw Gold/@@WithDrawGold>\
<Leave/@Exit>

#ELSEACT
Loadvalue A2 "QuestDiary\Guild\GoldStorage.txt" %GUILDNAME [Gold]
#ELSESAY
{FCOLOR/10}Legends Gold Storage{FCOLOR/12}\
Current Gold: {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\\
What do you wish to do?\\
<Input Amount Of Gold To Deposit Gold/@@DepositGold>\\
<Leave/@Exit>

;-----------------------------------------

[@@DepositGold]
#ACT
mov D2 %A2
mov D3 %INPUTSTR

#IF
CheckGold %D3
#ACT
Take Gold %D3
INC D2 %D3
SaveValue "QuestDiary\Guild\GoldStorage.txt" %GUILDNAME [Gold] %D2
#SAY
Done...\\
Guild Gold: {FCOLOR/10}<$OUTPUT(D2)>{FCOLOR/12}\\
<Leave/@Exit>
#ELSESAY
You do not have {FCOLOR/10}<$OUTPUT(D3)>{FCOLOR/12} Gold...\\
<Leave/@Exit>

;-----------------------------------------

[@@WithDrawGold]
#ACT
mov D2 %A2
mov D3 %INPUTSTR

#IF
Large D3 %D2
#SAY
sorry your guild only has {FCOLOR/10}<$OUTPUT(D2)>{FCOLOR/12} Gold...\\
<Leave/@Exit>

#ELSEACT
Give Gold %D3
Dec D2 %D3
SaveValue "QuestDiary\Guild\GoldStorage.txt" %GUILDNAME [Gold] %D2
#ELSESAY
Done...\\
Legends Guild Gold: {FCOLOR/10}<$OUTPUT(D2)>{FCOLOR/12}\\
<Leave/@Exit>

;-------------------------------------------------------------------------------

;;Ҫɾ