;;;;;;;;;;;;;NPC for JinchonTemple Quests - Toxin;;;;;;;;;;;;;

[@Main]
#IF
check [454] 1
#SAY
You've already completed my quest! You need to\
speak to my brother, Noah, for your next quest.\
\
<[ Close ]/@exit>\\\
#ELSEACT
goto @Main_1

;;;; ^^^ This section checks if Stage1 has already been completed ;;;;
;;;; ^^^ If flag [454] is off the script then checks if the mobs  ;;;;
;;;; ^^^ been killed, if not it then gives the quest, if it's     ;;;;
;;;; ^^^ on then it simply passes the player on to the next NPC.  ;;;;



[@Main_1]
#IF
check [453] 1
#SAY
Well I see what Frankie saw in you now, you\
really are a remarkable fighter.  Please accept\
this, it's not much but it's all I can afford\
to give right now.\\\
#ACT
give Gold 100000
set [453] 0
set [454] 1
#ELSEACT
goto @Main_2
break

;;;; ^^^ Second check to find out if the quest has been completed ;;;;
;;;; ^^^ but not ended.  After rewards are given flag [454] is    ;;;;
;;;; ^^^ set to on so the script will stop at the first check and ;;;;
;;;; ^^^ not double up on the rewards if clicked again.           ;;;;



[@Main_2]
#IF
check [451] 0
check [452] 0
#SAY
You need to see my brother, Frankie, before you\
come to see me.\
\
<[ Ok... ]/@exit>\\\
#ACT
break

;;;; ^^^ Checks if intro quest has been completed, if not it sends ;;;;
;;;; ^^^ player back to first NPC to complete the introduction.    ;;;;

#IF
check [451] 1
check [452] 0
#SAY
So you've proven yourself worthy of becoming a\
member of the ShadowGuard, but it's not as easy\
as Frankie might have led you to believe.  If\
you truly want to become one of the elites, you\
must complete the tasks I have for you.\
\
So what will you do?\
\
<[ I'm upto any challenge ]/@ShadowQuestStage1_0>\
<[ Forget it ]/@exit>\\\
break

;;;; ^^^ NPC Intro speach for Stage1 of the ShadowTemple quests.  ;;;;
;;;; ^^^ If accepted this screen only shows once, after this any  ;;;;
;;;; ^^^ players speaking to the NPC that haven't completed the   ;;;;
;;;; ^^^ quest will get the reminder speach further down.         ;;;;

#ELSESAY
Have you forgotten already? You need to go into\
ShadowTemple, take the NorthWest doorway to the\
ShadowPlains and when you find the lowest floor\
you need to kill the SHADOW??????\
\
Once you've done this come back and see me.\
\
<[ I'll do it! ]/@exit>\\\

;;;; ^^^ Reminder speach for the 1st stage of the main quest.     ;;;;
;;;; ^^^ Only active if flag [452] is on.			  ;;;;

[@ShadowQuestStage1_0]
#IF
#SAY
My task is simple... well maybe not... but\
if you can kill a monster for me I'll let my\
brothers know and maybe they'll give you\
another quest.  There is also a reward for\
your efforts, so don't think I'm as that\
tightfisted brother of mine.\
\
<[ Next ]/@ShadowQuestStage1_1>\\\

[@ShadowQuestStage1_1]
#IF
#ACT
set [452] 1
#SAY
Ok, first travel to the north of here and\
you'll come across the entrance to the\
ShadowTemple.  I've opened the door for you.\
\
Once you've entered there, head to the\
NorthWest doorway (127:101) and follow the path\
into the ShadowPlains.  You will find the\
sHADOW?????? on the lowest floor.  Kill it and\
return to me to claim your reward.\
\
<[ Ok, I'll go kill it now! ]/@exit>\\\

;;;; ^^^ Sets flag [452] on granting access to the ShadowTemple's   ;;;;
;;;; ^^^ first floors.  This quest/area is around level 50 to hunt  ;;;;
;;;; ^^^ and is 4 floors deep (including lobby).  After this 	    ;;;;
;;;; ^^^ section is activated the reminder will show instead of     ;;;;
;;;; ^^^ the stage one intro section.				    ;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;