;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[@main]
#IF
Check [266] 1
Check [267] 0
#ACT
FormatStr "FLD_QUEST ='Ali' and FLD_CHARACTER='%s'" %USERNAME
ReadValueSql "TBL_StingQuests" %A9 "FLD_Stage" @AliQuestStage
Break

#IF
Check [266] 1
Check [267] 1
#SAY
Skele is back to his normal self, thanks.\
<[ Exit ]/@exit>\\

#ELSESAY
How are you? Can you do me a favour?\
<[ Possibly... ]/@Main>\
#ELSEACT
Set  [266] 1


[@AliQuestStage()]
#IF
#ACT
Mov   D1   %ARG(1)

#IF
Equal  D1  0
#ACT
Goto @AliQuest0
Break

#IF
Equal  D1  1
#ACT
Goto @AliQuest1
Break

#IF
Equal  D1  2
#ACT
Goto @AliQuest2
Break

#IF
Equal  D1  3
#ACT
Goto @AliQuest3
Break

#IF
Equal  D1  4
#ACT
Goto @AliQuest4
Break

#IF
Equal  D1  5
#ACT
Goto @AliQuest5
Break

#IF
Equal  D1  6
#ACT
Goto @AliQuest6
Break

#IF
Equal  D1  7
#ACT
Goto @AliQuest7
Break

#IF
Equal  D1  8
#ACT
Goto @AliQuest8
Break

#IF
#SAY
<$OUTPUT(D1)> D1 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 0
[@AliQuest0]
#SAY
My pet skeleton has been devoured by a \
number of nasty creatures.  I need you to \
get him back for me by killing these \
horrible creatures... I will reward you.\
Are you brave enough to take on my quest?\\
<[ Yes sure, what do I have to do ]/@AliQuest0_1>\
<[ Maybe some other time, sorry ]/@exit>\\\
#ACT
Break

[@AliQuest0_1]
#SAY
The {FCOLOR/10}SpittingSpider{FCOLOR/12} enjoyed feasting on \
{FCOLOR/10}SkelesArms{FCOLOR/12}, kill him to retrieve these\
and bring them back to me, then I will \
tell you how to get back his legs..\\
<[ I'll go look now ]/@exit>\
#ACT
Mov  A0  %USERNAME
Mov  A1  "Ali"
Mov  D0  1
FormatStr "'%s','%s',%s" %A0 %A1 %D0
Mov A8 %A9
FormatStr "FLD_CHARACTER='%s' and FLD_QUEST='%s'" %A0 %A1
WriteValueSql "TBL_StingQuests" %A9 "FLD_CHARACTER,FLD_QUEST,FLD_STAGE" %A8

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 1
[@AliQuest1]
#SAY
Kill {FCOLOR/10}SpittingSpiders{FCOLOR/12} to retrieve\
{FCOLOR/10}SkelesArms{FCOLOR/12}, then return to me\\
<[ OK, thanks ]/@exit>\\
#ACT
Break

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 2
[@AliQuest2]

#IF
CheckItem SkelesArms 1
#SAY
Oh, thankyou so much. He now needs his\
legs, you will find these in the {FCOLOR/10}NorthAntColony{FCOLOR/12},\
those {FCOLOR/10}SoldierAnts{FCOLOR/12} are a right pain, they \
surrounded poor Skele, there was nothing\
he could do. Please get {FCOLOR/10}SkelesLegs{FCOLOR/12} back\
and return them to me\\
<[ Yes, no problem ]/@AliQuest2_1>\
<[ No, I'm busy ]/@exit>\\\

#ACT
Take SkelesArms 1
Mov  A0  %USERNAME
Mov  A1  "Ali"
Mov  D0  3
FormatStr "FLD_STAGE=%s" %D0
Mov A8 %A9
FormatStr "FLD_CHARACTER='%s' and FLD_QUEST='%s'" %A0 %A1
UpdateValueSql "TBL_StingQuests" %A9 %A8
Break

#ELSESAY
Where did you put {FCOLOR/10}SkelesArms{FCOLOR/12}.. I really need them!\\
<[ I'll go fetch them ]/@exit>\\
#ELSEACT
Break

[@AliQuest2_1]
#SAY
Nice one.. \\
<[ Exit ]/@exit>\
#ACT
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 3
[@AliQuest3]
#SAY
Kill {FCOLOR/10}SoldierAnts{FCOLOR/12} to retrieve\
{FCOLOR/10}SkelesLegs{FCOLOR/12}, then return to me.  It was\
Lost in {FCOLOR/10}NorthAntColony{FCOLOR/12}\\
<[ OK, thanks ]/@exit>\\
#ACT
Break

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 4
[@AliQuest4]

#IF
CheckItem SkelesLegs 1
#SAY
Thankyou, Skele now needs his torso back \
from those nasty {FCOLOR/10}DesertHermit{FCOLOR/12} before they\
bury it the sand. Please hurry, and bring\
{FCOLOR/10}SkelesTorso{FCOLOR/12} back to me.\\
<[ Yeah, sure ]/@AliQuest4_1>\
<[ No way, do you think Im nuts ]/@exit>\\\

#ACT
Take SkelesLegs 1
Mov  A0  %USERNAME
Mov  A1  "Ali"
Mov  D0  5
FormatStr "FLD_STAGE=%s" %D0
Mov A8 %A9
FormatStr "FLD_CHARACTER='%s' and FLD_QUEST='%s'" %A0 %A1
UpdateValueSql "TBL_StingQuests" %A9 %A8
Break

#ELSESAY
What have you done with {FCOLOR/10}SkelesLegs{FCOLOR/12}!\\
<[ Err.. it was here a second ago! ]/@exit>\

#ELSEACT
Break

[@AliQuest4_1]
#SAY
Keep it up.. thanks\\
<[ Exit ]/@exit>\
#ACT

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 5
[@AliQuest5]
#SAY
Kill {FCOLOR/10}DesertHermit{FCOLOR/12} to retrieve\
{FCOLOR/10}SkelesTorso{FCOLOR/12}, then return to me\\
<[ OK, thanks ]/@exit>\\
#ACT
Break

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 6
[@AliQuest6]

#IF
CheckItem SkelesTorso 1

#SAY
I am so delighted, thankyou.  Skele is almost\
complete, all that he needs now is his head,\
which the {FCOLOR/10}ZumaGuard{FCOLOR/12} picked up on its way\
home. Please get it back for me, and I\
will reward you upon your return.\
You will find him in {FCOLOR/10}ZumaTemple5F{FCOLOR/12}\\
<[ Here to Please! ]/@exit>\

#ACT
Take SkelesTorso 1
Mov  A0  %USERNAME
Mov  A1  "Ali"
Mov  D0  7
FormatStr "FLD_STAGE=%s" %D0
Mov A8 %A9
FormatStr "FLD_CHARACTER='%s' and FLD_QUEST='%s'" %A0 %A1
UpdateValueSql "TBL_StingQuests" %A9 %A8
Break

#ELSESAY
Come on.. don't hide it from me.. where is\
{FCOLOR/10}SkelesTorso{FCOLOR/12}?\\
<[ I have it somewhere ]/@exit>\

#ELSEACT
Break
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 7
[@AliQuest7]
#SAY
Kill {FCOLOR/10}ZumaGuard{FCOLOR/12} to retrieve\
{FCOLOR/10}SkelesHead{FCOLOR/12}, then return to me.  It was\
Lost in {FCOLOR/10}ZumaTemple5F{FCOLOR/12}\\
<[ OK, thanks ]/@exit>\\
#ACT
Break

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Part 8
[@AliQuest8]
#IF
!CheckMonRecall
#ACT
Goto @PetAlready
break

#IF
CheckItem SkelesHead 1
#SAY
Thankyou, I don't know what I would of done\
without your help. To help me get Skele back\
to his usual self, you can use him as your\
pet for the next 60 minutes, then he will \
automatically return to me, and as I am \
so grateful here's a healthy sum of gold too.\\
<[ :D ]/@AliQuest4_1>\
#ACT
Set  [267]  1
MonRecall AliSkele 1 7
Take SkelesHead 1
Give Gold 250000
Mov  A0  %USERNAME
Mov  A1  "Ali"
Mov  D0  9
FormatStr "FLD_STAGE=%s" %D0
Mov A8 %A9
FormatStr "FLD_CHARACTER='%s' and FLD_QUEST='%s'" %A0 %A1
UpdateValueSql "TBL_StingQuests" %A9 %A8
Break

#ELSESAY
What have you done with {FCOLOR/10}SkelesHead{FCOLOR/12}!\\
<[ I dunno.. I go look ]/@exit>\

#ELSEACT
Break

[@PetAlready]
#SAY
You already have a pet, please get rid of it\
so you can take my Skele.\\
<[ Exit ]/@exit>\\\

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;