;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[@Marriage]
{
#Define N50{START} N50
#Define N51{WEDDING} N51
#Define N53{TIME} N53
#Define N54{TRY} N54
#Define N55{WAITINGTIMEOUT} N55
#Define N56{MAN} N6
#Define N57{GIRL} N7

#Define B1{MANNAME} B1
#Define B2{GIRLNAME} B2
#Define B3{INPUTGIRLNAME} B3

#IF
Equal N50{START} 1

#SAY
There is a ceremony in Progress, Please wait..\


#ELSESAY
If you wish to get Married, can the groom stand at (42,30)\
and the Bride (43,31)\
You have 10 Minutes to get married.  If you go over, you\
will have to start again\
Please bear in mind you cannot use a special ring as\
a wedding ring\
Anyone caught using one of these will have the ring\
deleted!\\
<[ Get Married ]/@wantGetMarried>\
<[ Get Divorced ]/@wantDivorce>\
<[ Remove Wedding Ring ]/@TakeMarriedRing>\

#IF
Equal B1{MANNAME} %USERNAME

#SAY
<[ Cancel Wedding Application ]/@PreCancelWedding>\

#IF
IsAdmin

#SAY
<[ Reset Wedding Variables ]/@ResetWeddingVariables>\

#IF
#SAY
<[ Help ]/@MarriageQuestion>\
<[ Exit ]/@exit>\

[@MarriageQuestion]
#IF

#SAY
To get married you need to follow these Rules\
you need to be {FCOLOR/10}Level 22+{FCOLOR/12}\
You must be {FCOLOR/10}Single{FCOLOR/12}\
The Groom must stand at {FCOLOR/10}(42,30){FCOLOR/12}\
The Bride must stand at {FCOLOR/10}(43,31){FCOLOR/12}\
Then you must choose {FCOLOR/10}Marriage Application{FCOLOR/12}\
The ceremony will cost both characters {FCOLOR/10}500,000 Gold{FCOLOR/12}\
<[ Exit ]/@exit>\

[@wantGetMarried]
#IF
!CheckLevel 22

#SAY
To get married you need to be {FCOLOR/10}Level 22+{FCOLOR/12}\
<[ Exit ]/@exit>\

#ACT
break

#IF
CheckMarriage

#SAY
To get married you need to be {FCOLOR/10}Single{FCOLOR/12}\
<[ Exit ]/@exit>\

#ACT
break

#IF
Gender [man]
#ACT
goto @wantGetMarried_man
#ELSEACT
goto @wantGetMarried_woman



[@wantGetMarried_woman]
#IF
!CheckPos 10_000,43,31,1

#SAY
The Groom must stand at {FCOLOR/10}(42,30){FCOLOR/12}\
<[ Exit ]/@exit>\

#ACT
break

#IF
equal N56{MAN} 1
equal B3{INPUTGIRLNAME} %USERNAME
#ELSEACT
SysMsg "The Groom has not applied for Marriage"
close
break

#IF
CheckGold 500000
#ACT
Take Gold 500000
mov N57{GIRL} 1
mov B2{GIRLNAME} %USERNAME
SysMsg "Marriage Application Completed"
close
#ELSEACT
SysMsg "This ceremony costs 500,000 Gold.  You need more Gold"
close



[@wantGetMarried_man]
#IF
!CheckPos 10_000,42,30,1

#SAY
The Bride must stand at {FCOLOR/10}(43,31){FCOLOR/12}\
<[ Exit ]/@exit>\

#ACT
break

#IF
Equal B1{MANNAME} ""

#SAY
What is the lovely brides name?\
<[ Enter Brides Name ]/@@InputMarried_Woman>\

#ELSESAY
You cannot apply for marriage at this time\
<[ Exit ]/@Exit>\

[@@InputMarried_Woman]
#IF
Mov B5 %INPUTSTR
!Equal B5 ""

#SAY
The brides name is <$INPUTSTR>?\
<[ Yes ]/@ProcessMarried>\
<[ No ]/@wantGetMarried_man>\

[@ProcessMarried]
#IF
Equal N56{MAN} 1

#SAY
There is a ceremony in Progress, Please wait..

#ACT
break

#IF
!Equal B1{MANNAME} ""

#SAY
There is a ceremony in Progress, Please wait..

#ACT
break

#IF
!Equal B3{INPUTGIRLNAME} ""

#SAY
There is a ceremony in Progress, Please wait..

#ACT
break


#IF
!CheckGold 500000
#ACT
SysMsg "This ceremony costs 500,000 Gold.  You need more Gold"
close
break
#ELSEACT
Take Gold 500000
mov B1{MANNAME} %USERNAME
mov B3{INPUTGIRLNAME} %B5
mov N56{MAN} 1
mov N55{WAITINGTIMEOUT} 0
Delaygoto [Grobal] 5 @startWeddingloop
SysMsg "Marriage Application Completed"
close


[@startWeddingloop]
#IF
Equal N50{START} 1
#ACT
break

#IF
Inc N55{WAITINGTIMEOUT} 1
Large N55{WAITINGTIMEOUT} 5
#ACT
Sysmsg "I am sorry, you took too long.  Ceremony is cancelled."
goto @CancelWedding
break

#IF
Equal N56{MAN} 1
Equal N57{GIRL} 1
#ELSEACT
SysMsg "Waiting for the Bride to Apply"
Delaygoto [Grobal] 5 @startWeddingloop
break

#IF
#ACT
Mov N50{START} 1
mov N51{WEDDING} 1
Mov N53{TIME} 0
EventMsg "10_000" "<$OUTPUT(B1)> and <$OUTPUT(B2)> your wedding ceremony is beginning" 10005
SysMsg "Preparing wedding ceremony"
Delaygoto [Grobal] 10 @weddingCeremony
close



[@weddingCeremony]
#IF
Equal N51{WEDDING} 0
#ACT
Sysmsg "Wedding ceremony is cancelled"
goto @CancelWedding
break

#IF
Large N53{TIME} 60
#ACT
EventMsg "10_000" "I am sorry, you took too long.  Ceremony is cancelled." 10005
goto @CancelWedding
break

#IF
Equal N51{WEDDING} 1
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> and <$OUTPUT(B2)>'s wedding ceremony is about to begin, all guests are asked to stand and be quiet during this ceremony." 10005
Mov N51{WEDDING} 2
Inc N53{TIME} 1
Delaygoto [Grobal] 20 @weddingCeremony
break

#IF
Equal N51{WEDDING} 2
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> do you want to marry <$OUTPUT(B2)>, please reply 'Yes'" 10005
Mov N54{TRY} 5
Mov N51{WEDDING} 3
CaptureSaying %B1 @ListenSayYes_man
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony
break

#IF
Equal N51{WEDDING} 3
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> reply 'Yes' or 'No'." 10005
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony
break

#IF
Equal N51{WEDDING} 4
#ACT
Eventmsg "10_000" "<$OUTPUT(B2)> do you want to marry <$OUTPUT(B1)>, please reply 'Yes'" 10005
Mov N54{TRY} 5
Mov N51{WEDDING} 5
CaptureSaying %B2 @ListenSayYes_woman
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony
break

#IF
Equal N51{WEDDING} 5
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> reply 'Yes' or 'No'." 10005
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony
break

#IF
Equal N51{WEDDING} 6
#ACT
Eventmsg "10_000" "Now to exchange the rings.  Open a Trade window and trade rings." 10005
GetMarried %B1 %B2
mov N51{WEDDING} 7
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony
break

#IF
Equal N51{WEDDING} 7
CheckMarriageRing %B1
CheckMarriageRing %B2
#ACT
EventMsg "10_000" "I now pronounce you man and wife! Live long and Prosper!!" 10005
goto @cancelWedding
Break

#IF
#ACT
Inc N53{TIME} 1
Delaygoto [Grobal] 10 @weddingCeremony



[@ListenSayYes_man]
#IF
Equal N51{WEDDING} 0
#ACT
Sysmsg "Wedding ceremony is cancelled"
goto @cancelWedding
CaptureSaying ""
break

#IF
#ACT
mov B9 %INPUTSTR
mov P1 %@GetFace
EventMsg "10_000" "<$OUTPUT(B9)>" %P1

#IF
Equal N51{WEDDING} 3
Equal B9 "Yes"
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> replies '<$OUTPUT(B9)>'." 10005
Mov B9 ""
Mov N51{WEDDING} 4
CaptureSaying ""
break

#IF
Equal N51{WEDDING} 3
Equal B9 "No"
#ACT
EventMsg "10_000" "<$OUTPUT(B1)> replies '<$OUTPUT(B9)>'." 10005
EventMsg "10_000" "OMG!!! <$OUTPUT(B1)> Has said No!!!!!!" 10005
Mov B9 ""
CaptureSaying ""
goto @cancelWedding
Break

#IF
Large N54{TRY} 0
#ACT
SysMsg "You have <$OUTPUT(N54)> attempts left .Please reply 'Yes' or 'No'."
Dec N54{TRY} 1
break
#ELSEACT
EventMsg "10_000" "Its all over... " 10005
Mov B9 ""
CaptureSaying ""
goto @cancelWedding
Break



[@ListenSayYes_woman]
#IF
Equal N51{WEDDING} 0
#ACT
goto @cancelWedding
CaptureSaying ""
break

#IF
#ACT
mov B9 %INPUTSTR
mov P1 %@GetFace
EventMsg "10_000" "<$OUTPUT(B9)>" %P1

#IF
Equal N51{WEDDING} 5
Equal B9 "Yes"
#ACT
EventMsg "10_000" "<$OUTPUT(B2)> replies '<$OUTPUT(B9)>'." 10005
Mov B9 ""
Mov N51{WEDDING} 6
CaptureSaying ""
break

#IF
Equal N51{WEDDING} 5
Equal B9 "No"
#ACT
EventMsg "10_000" "<$OUTPUT(B2)> replies '<$OUTPUT(B9)>'." 10005
EventMsg "10_000" "OMG!!! <$OUTPUT(B1)> Has said No!!!!!!" 10005
Mov B9 ""
CaptureSaying ""
goto @cancelWedding
Break

#IF
Large N54{TRY} 0
#ACT
SysMsg "You have <$OUTPUT(N54)> attempts left .Please reply 'Yes' or 'No'."
Dec N54{TRY} 1
break
#ELSEACT
EventMsg "10_000" "Its all over... " 10005
Mov B9 ""
CaptureSaying ""
goto @cancelWedding
Break


[@GetFace]
#IF
CheckJob Warrior
#ACT
mov P1 0

#IF
CheckJob Wizard
#ACT
mov p1 1

#IF
CheckJob Taoist
#ACT
mov p1 2

#IF
#ACT
mul p1 2
mov p1 p9

#IF
gender woman
#ACT
inc p1

#IF
#ACT
inc p1 20000

#SAY
<$OUTPUT(p1)>

[@wantDivorce]
#IF
CheckMarriage

#SAY
Are you sure you want to get Divorced?\
It will cost you 1000000 Gold!\
<[ Yes ]/@divorcenow>\
<[ No ]/@Exit>\


#ELSESAY
You are not married!\
<[ Exit ]/@Exit>\

[@divorcenow]
#IF
checkgold 1000000
#ACT
take Gold 1000000
Divorce
close


[@TakeMarriedRing]
#IF
CheckMarriage

#SAY
Are you sure you want to remove your wedding ring?\
This will cost you 200,000 Gold!\\
<[ Yes ]/@ExchangeMarriedRing>\
<[ No ]/@Exit>\


#ELSESAY
You are not married!\
<[ Exit ]/@Exit>\

[@ExchangeMarriedRing]
#IF
checkgold 200000
#ACT
take Gold 200000
CancelMarriageRing
SysMsg "You no longer have a wedding ring, trade with your spouse for a new Ring"
close

#ELSESAY
You don't have enough Gold!\
<[ Exit ]/@Exit>\

[@ResetWeddingVariables]
#ACT
goto @cancelWedding
close
break


[@PreCancelWedding]
#ACT
SysMsg "Wedding Cancelled."
goto @CancelWedding
break




[@CancelWedding]
#ACT
Mov N50{START} 0
Mov N51{WEDDING} 0
Mov N53{TIME} 0
Mov N54{TRY} 0
Mov N55{WAITINGTIMEOUT} 0
Mov N56{MAN} 0
Mov N57{GIRL} 0
Mov B1{MANNAME} ""
Mov B2{GIRLNAME} ""
Mov B3{INPUTGIRLNAME} ""
Mov B4 ""
Mov B8 ""
Mov B9 ""
close
break
}
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;