;;不要删掉此行

[@PotionShopMain]
{
#SAY
Welcome <$USERNAME>,\
How may i help you?\
{FCOLOR/10}
Buy: <Potion/@Buy>\
Sell: <Potion/@noSell>\
Make: <Item/@Make_Item>\
<Exchange EXP Potion/@ExpPotion>\\
<Talk with/@CALL_Npc_TodayQuest> <$NPCNAME>\\
<Leave/@Exit>

;--------------------------------------------

[@CALL_Npc_TodayQuest]
#CALL [TodayQuest\QT_NPCSetting.txt] @NPCSetDairyQuest

;--------------------------------------------

[@noSell]
#SAY
Sorry but i have had a problem with\
trouble makers who seem to find it funny\
to con me now i shall only buy potions\
off my trusted dealer...\\
<Leave/@Exit>

[@Buy]
#SAY
Please select what you wish to buy.\\
<Back/@Main>\
<Leave/@Exit>

;--------------------------------------------

[@Sell]
#SAY
Please select what you wish to sell.\\
<Back/@Main>\
<Leave/@Exit>

;--------------------------------------------

[@Make_Item]
#SAY
Please select what you wish to make.\\
<Potions/@MakePotion>\
<Talismans/@MakeTalisman>\
;<Poison/@MakePoison>\
\<Back/@Main>\
<Leave/@Exit>

;--------------------------------------------

[@MakePotion]
#SAY
Please select what you wish to make.\\
<HP Potion (S)/@MakePotion2(HPPotion,SnakeBile,5)>\
<HP Potion (M)/@MakePotion2(HPPotion(M),SkeletonBone,10)>\
<HP Potion (L)/@MakePotion2(HPPotion(L),StoneStatuePiece,5)>\
;<HP Potion (XL)/@MakePotion2(DarkPrajnaJemStone,5)>\\

<MP Potion (S)/@MakePotion2(MPPotion,SnakeBile,5)>\
<MP Potion (M)/@MakePotion2(MPPotion(M),SkeletonBone,10)>\
<MP Potion (L)/@MakePotion2(MPPotion(L),StoneStatuePiece,5)>\
;<MP Potion (XL)/@MakePotion2(MPPotion(XL),DarkPrajnaJemStone,5)>\
<Back/@Main>\
<Leave/@Exit>

;--------------------------------------------

[@MakePotion2()]
#IF
#ACT
Mov A1{ITEM} %ARG(1)
Mov A2{NEEDITEM} %ARG(2)
Mov A3{ITEMAMOUNT} %ARG(3)
#SAY
To make {FCOLOR/10} 10{FCOLOR/12} x{FCOLOR/10} <$OUTPUT(A1)>{FCOLOR/12}\
you need {FCOLOR/10}<$OUTPUT(A3)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\\
<Make/@MakePotion3> {FCOLOR/15}<$OUTPUT(A1)> <Now/@MakePotion3>\
<Leave/@Exit>\

;------------------------------------

[@MakePotion3]
#IF
CheckItem %A2 %A3
#ACT
Give %A1 10
Take %A2 %A3
close
#ELSESAY
you do not have {FCOLOR/10}<$OUTPUT(A3)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\\
<Leave/@Exit>\

;--------------------------------------------

[@MakeTalisman]
#SAY
Please select what you wish to make.\\{FCOLOR/10}
Talisman: <(S)/@MakeTalisman2(Talisman(S),SkeletonBone,3,ScorpionTail,2)>|
<(M)/@MakeTalisman2(Talisman(M),SkeletonBone,6,ScorpionTail,4)>|
<(L)/@MakeTalisman2(Talisman(L),SkeletonBone,9,ScorpionTail,6)>\

Talisman(Ignis): <(S)/@MakeTalisman2(Talisman(Ignis)(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(Talisman(Ignis)(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(Talisman(Ignis)(L),ZombieBone,12,ScorpionTail,6)>\

Talisman(Gelu): <(S)/@MakeTalisman2(Talisman(Gelu)(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(Talisman(Gelu)(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(Talisman(Gelu)(L),ZombieBone,12,ScorpionTail,6)>\

Talisman(Fulmen): <(S)/@MakeTalisman2(Talisman(Fulmen)(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(Talisman(Fulmen)(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(Talisman(Fulmen)(L),ZombieBone,12,ScorpionTail,6)>\

Talisman(Ventus): <(S)/@MakeTalisman2(Talisman(Ventus)(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(Talisman(Ventus)(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(Talisman(Ventus)(L),ZombieBone,12,ScorpionTail,6)>\\

Holy Talisman: <(S)/@MakeTalisman2(HolyTalisman(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(HolyTalisman(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(HolyTalisman(L),ZombieBone,12,ScorpionTail,6)>\

Dark Talisman: <(S)/@MakeTalisman2(DarkTalisman(S),ZombieBone,4,ScorpionTail,2)>|
<(M)/@MakeTalisman2(DarkTalisman(M),ZombieBone,8,ScorpionTail,4)>|
<(L)/@MakeTalisman2(DarkTalisman(L),ZombieBone,12,ScorpionTail,6)>\\

Soul Talisman: <(S)/@MakeTalisman2(SoulTalisman(S),StoneStatuePiece,5,ScorpionTail,2)>|
<(M)/@MakeTalisman2(SoulTalisman(M),StoneStatuePiece,10,ScorpionTail,4)>|
<(L)/@MakeTalisman2(SoulTalisman(L),StoneStatuePiece,15,ScorpionTail,6)>\\
<Back/@Main>\
<Leave/@Exit>

;--------------------------------------------

[@MakeTalisman2()]
#IF
#ACT
Mov A1{ITEM} %ARG(1)
Mov A2{NEEDITEM1} %ARG(2)
Mov A3{ITEM1AMOUNT} %ARG(3)
Mov A4{NEEDITEM2} %ARG(4)
Mov A5{ITEM2AMOUNT} %ARG(5)
#SAY
To make {FCOLOR/10} 10{FCOLOR/12} x{FCOLOR/10} <$OUTPUT(A1)>{FCOLOR/12}\
you need {FCOLOR/10}<$OUTPUT(A3)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\
and {FCOLOR/10}<$OUTPUT(A5)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A4)>{FCOLOR/12}\\
<Make/@MakeTalisman3> {FCOLOR/15}<$OUTPUT(A1)> <Now/@MakeTalisman3>\
<Leave/@Exit>\

;------------------------------------

[@MakeTalisman3]
#IF
CheckItem %A2 %A3
CheckItem %A4 %A5
#ACT
Give %A1 10
Take %A2 %A3
Take %A4 %A5
close
#ELSESAY
you do not have {FCOLOR/10}<$OUTPUT(A3)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A2)>{FCOLOR/12}\
or {FCOLOR/10}<$OUTPUT(A5)>{FCOLOR/12} x {FCOLOR/10}<$OUTPUT(A4)>{FCOLOR/12}\\
<Leave/@Exit>\

;--------------------------------------------

[@ExpPotion]
#IF
CheckItem ExpPotion(1000) 1
#ACT
GoTo @CheckLEVEL
#ELSESAY
You must have a ExpPotion(1000)...\\
<Leave/@Exit>

[@CheckLEVEL]
#IF
CheckLevel 11
CheckItem ExpPotion(1000) 1
#ACT
GiveExp %USERNAME 10000
Take ExpPotion(1000) 1
CLOSE
#ELSESAY
You must be level 11...\\
<Leave/@Exit>

}

;;不要删掉此行